100 REM                          SIODOS.BAS
110 REM
120 REM              Copyright 1998 by Industrologic, Inc.
130 REM
140 REM When used in its entirety, this BASIC language source code can be
150 REM run using GWBASIC, or compiled and run using Microsoft QuickBASIC.
160 REM (Use the extended communication buffer option for both,  /C:32767)
170 REM 
180 REM This program is essentially a "dumb terminal" program capable of
190 REM sending commands to the SIO1000 manually and receiving its responses,
200 REM along with the additional capabilty to send preselected commands to
210 REM the SIO1000 and display those responses.
220 REM
230 REM An effort was made to make the individual routines that communicate
240 REM with the SIO1000 as self-contained as possible so that they can be
250 REM used alone. For this reason in-line code has been used in some of
260 REM the routines that could have been put in a common subroutine.
270 REM
280 KEY OFF:FOR A=1 TO 10:KEY A,"":NEXT A:LOCATE ,,0
290 CLS
300 PRINT "                                   SIODOS"
310 PRINT "                    Copyright 1998 by Industrologic, Inc."
320 PRINT:PRINT
330 PRINT "       This program is provided by Industrologic, Inc. for the sole purpose"
340 PRINT "       of demonstrating how to communicate with the Industrologic, Inc."
350 PRINT "       model SIO1000 interface, and for no other purpose."
360 PRINT:PRINT
370 PRINT "                            Warning - Disclaimer"
380 PRINT
390 PRINT "       This software is provided `as is' without warranty of any kind."
400 PRINT "       The entire risk as to the result and performance of this software"
410 PRINT "       or any part of it as well as its fitness for a particular use is"
420 PRINT "       assumed by the user. Neither Industrologic, Inc. nor any of its"
430 PRINT "       employees shall have any liability for, nor responsibility to any"
440 PRINT "       person or entity with respect to loss or damage caused or alleged"
450 PRINT "       to be caused directly or indirectly by this software."
460 PRINT:PRINT:PRINT
470 PRINT "                          hit any key to continue"
480 IN$=INKEY$:IF IN$="" THEN 480
490 REM ---------------------------------------------------------------------
500 CLS
520 PRINT "Industrologic, Inc. SIO-1000 Demonstration/Test Program"
530 PRINT "Version 9/1/98"
550 PRINT
560 PRINT "----- COM1 -----     ----- COM2 -----"
570 PRINT "(A)    150,N,8,1     (B)    150,N,8,1"
580 PRINT "(C)    300,N,8,1     (D)    300,N,8,1"
590 PRINT "(E)    600,N,8,1     (F)    600,N,8,1"
600 PRINT "(G)   1200,N,8,1     (H)   1200,N,8,1"
610 PRINT "(I)   2400,N,8,1     (J)   2400,N,8,1"
620 PRINT "(K)   4800,N,8,1     (L)   4800,N,8,1"
630 PRINT "(M)   9600,N,8,1     (N)   9600,N,8,1"
640 PRINT "(0)  19200,N,8,1     (P)  19200,N,8,1"
650 PRINT:PRINT "Select port and baud rate"
660 PRINT "or hit ESCape to exit program"
700 B$=INKEY$:IF B$="" THEN 700
710 IF B$="A" OR B$="a" THEN PORT$="COM1":BAUD$="150":GOTO 900
720 IF B$="B" OR B$="b" THEN PORT$="COM2":BAUD$="150":GOTO 900
730 IF B$="C" OR B$="c" THEN PORT$="COM1":BAUD$="300":GOTO 900
740 IF B$="D" OR B$="d" THEN PORT$="COM2":BAUD$="300":GOTO 900
750 IF B$="E" OR B$="e" THEN PORT$="COM1":BAUD$="600":GOTO 900
760 IF B$="F" OR B$="f" THEN PORT$="COM2":BAUD$="600":GOTO 900
770 IF B$="G" OR B$="g" THEN PORT$="COM1":BAUD$="1200":GOTO 900
780 IF B$="H" OR B$="h" THEN PORT$="COM2":BAUD$="1200":GOTO 900
790 IF B$="I" OR B$="i" THEN PORT$="COM1":BAUD$="2400":GOTO 900
800 IF B$="J" OR B$="j" THEN PORT$="COM2":BAUD$="2400":GOTO 900
810 IF B$="K" OR B$="k" THEN PORT$="COM1":BAUD$="4800":GOTO 900
820 IF B$="L" OR B$="l" THEN PORT$="COM2":BAUD$="4800":GOTO 900
830 IF B$="M" OR B$="m" THEN PORT$="COM1":BAUD$="9600":GOTO 900
840 IF B$="N" OR B$="n" THEN PORT$="COM2":BAUD$="9600":GOTO 900
850 IF B$="O" OR B$="o" THEN PORT$="COM1":BAUD$="19200":GOTO 900
860 IF B$="P" OR B$="p" THEN PORT$="COM2":BAUD$="19200":GOTO 900
870 IF B$=CHR$(27) THEN END
880 GOTO 700
900 ON ERROR GOTO 5500:REM IF ERROR OPENING PORT
910 CLOSE:OPEN PORT$+":"+BAUD$+",N,8,1,CS,DS,CD" AS #1
920 ON ERROR GOTO 0
990 REM -----
1000 CLS
1010 PRINT "Industrologic, Inc. SIO-1000 Demonstration/Test Program"
1020 PRINT
1030 PRINT "(T)  Terminal emulation mode"
1040 PRINT "(C)  Continuous display/set functions"
1050 PRINT:PRINT "Select function or hit ESCape to go back"
1100 B$=INKEY$:IF B$="" THEN 1100
1120 IF B$="T" OR B$="t" THEN 1500
1130 IF B$="C" OR B$="c" THEN 6000
1140 IF B$=CHR$(27) THEN 500
1150 GOTO 1100
1490 REM ---------------------------------------------------------------------
1500 CLS
1510 PRINT "Industrologic, Inc. SIO-1000 Demonstration/Test Program"
1520 PRINT "Terminal emulation mode"
1530 PRINT
1540 PRINT "Commands can be entered manually with their hexidecimal values, or"
1550 PRINT "the following keys can be used to enter commands with decimal values"
1560 PRINT
1570 PRINT "     Read Inputs:
1580 PRINT "F1   Digital Inputs"
1590 PRINT "F2   Analog Input 0"
1600 PRINT "F3   Analog Input 1"
1610 PRINT "F4   Pulse Counter Input          Shift F4   Read Counter & reset"
1620 PRINT "F5   Send SIO ID characters       Shift F5   Reset Hardware & send ID"
1630 PRINT
1640 PRINT "     Read set value of outputs:              Set outputs:"
1650 PRINT "F6   Digital Output               Shift F6   Digital Outputs"
1660 PRINT "F7   Analog Output 0              Shift F7   Analog Output 0"
1670 PRINT "F8   Analog Output 1              Shift F8   Analog Output 1"
1680 PRINT "F9   Waveform Output frequency    Shift F9   Waveform Output frequency"
1690 PRINT "F10  Waveform Output duty cycle   Shift F10  Waveform Output duty cycle"
1700 PRINT
1710 PRINT "Space Bar   Redisplay this list of commands"
1720 PRINT
1730 PRINT "ESCape  Exit terminal emulation"
1740 LOCATE ,,1
1750 REM ----- ENTRY POINT AFTER COMMUNICATION ERROR
2000 ON ERROR GOTO 5000:REM IF ERROR DURING COMMUNICATION
2010 REM ----- CHECK FOR CHARACTER AT PORT
2100 IF EOF(1) THEN 2200
2110 A$=INPUT$(1,#1)
2120 IF A$=CHR$(8) THEN A$=CHR$(29)+" "+CHR$(29):REM SPECIAL CASE FOR BACKSPACE
2130 IF A$=CHR$(10) THEN 2100:REM DO NOT DISPLAY IF LINE FEED
2140 PRINT A$;
2150 REM ----- CHECK FOR KEY HIT
2200 B$=INKEY$:IF B$="" THEN 2000
2210 IF B$=CHR$(0)+CHR$(59) THEN GOSUB 3000:GOTO 2100:REM F1
2220 IF B$=CHR$(0)+CHR$(60) THEN GOSUB 3100:GOTO 2100:REM F2
2230 IF B$=CHR$(0)+CHR$(61) THEN GOSUB 3200:GOTO 2100:REM F3
2240 IF B$=CHR$(0)+CHR$(62) THEN GOSUB 3400:GOTO 2100:REM F4
2250 IF B$=CHR$(0)+CHR$(63) THEN GOSUB 2600:GOTO 2100:REM F5
2260 IF B$=CHR$(0)+CHR$(64) THEN GOSUB 3500:GOTO 2100:REM F6
2270 IF B$=CHR$(0)+CHR$(65) THEN GOSUB 3600:GOTO 2100:REM F7
2280 IF B$=CHR$(0)+CHR$(66) THEN GOSUB 3700:GOTO 2100:REM F8
2290 IF B$=CHR$(0)+CHR$(67) THEN GOSUB 3800:GOTO 2100:REM F9
2300 IF B$=CHR$(0)+CHR$(68) THEN GOSUB 3900:GOTO 2100:REM F10
2310 IF B$=" " THEN 1500:REM REDISPLAY MENU
2320 IF B$=CHR$(27) THEN ON ERROR GOTO 0:GOTO 1000:REM ESCAPE KEY TO EXIT
2330 IF B$=CHR$(0)+CHR$(87) THEN GOSUB 3430:GOTO 2100:REM SHIFT F4
2340 IF B$=CHR$(0)+CHR$(88) THEN GOSUB 2500:GOTO 2100:REM SHIFT F5
2350 IF B$=CHR$(0)+CHR$(89) THEN GOSUB 4000:GOTO 2100:REM SHIFT F6
2360 IF B$=CHR$(0)+CHR$(90) THEN GOSUB 4200:GOTO 2100:REM SHIFT F7
2370 IF B$=CHR$(0)+CHR$(91) THEN GOSUB 4400:GOTO 2100:REM SHIFT F8
2380 IF B$=CHR$(0)+CHR$(92) THEN GOSUB 4600:GOTO 2100:REM SHIFT F9
2390 IF B$=CHR$(0)+CHR$(93) THEN GOSUB 4800:GOTO 2100:REM SHIFT F10
2400 PRINT #1,B$;
2410 GOTO 2000
2420 REM ----------
2500 PRINT "Sending R<CR>":REM RESET HARDWARE AND REQUEST ID CHARACTERS
2510 PRINT #1, "R"
2520 RETURN
2530 REM ----------
2600 PRINT "Sending r<CR>":REM REQUEST ID CHARACTERS
2610 PRINT #1, "r"
2620 RETURN
2630 REM ----------
3000 PRINT "Sending P<CR>":REM READ DIGITAL INPUT PORT
3010 PRINT #1, "P"
3020 RETURN
3030 REM ----------
3100 PRINT "Sending A<CR>":REM READ ANALOG INPUT 0
3110 PRINT #1, "A"
3120 RETURN
3130 REM ----------
3200 PRINT "Sending B<CR>":REM READ ANALOG INPUT 1
3210 PRINT #1, "B"
3220 RETURN
3230 REM ----------
3400 PRINT "Sending C<CR>":REM READ COUNT
3410 PRINT #1, "C"
3420 RETURN
3425 REM ----------
3430 PRINT "Sending c<CR>":REM READ COUNT AND RESET COUNTER
3440 PRINT #1, "c"
3450 RETURN
3460 REM ----------
3500 PRINT "Sending p<CR>":REM READ DIGITAL OUTPUT PORT SET VALUE
3510 PRINT #1, "p"
3520 RETURN
3530 REM ----------
3600 PRINT "Sending a<CR>":REM READ ANALOG OUTPUT 0 SET VALUE
3610 PRINT #1, "a"
3620 RETURN
3630 REM ----------
3700 PRINT "Sending b<CR>":REM READ ANALOG OUTPUT 1 SET VALUE
3710 PRINT #1, "b"
3720 RETURN
3730 REM ----------
3800 PRINT "Sending f<CR>":REM READ WAVEFORM FREQUENCY MODE SET VALUES
3810 PRINT #1, "f"
3820 RETURN
3830 REM ----------
3900 PRINT "Sending w<CR>":REM READ WAVEFORM DUTY CYCLE MODE SET VALUES
3910 PRINT #1, "w"
3920 RETURN
3930 REM ----------
4000 PRINT "Enter Digital Output port value in decimal from 0 to 255: ";
4010 LINE INPUT I$:I=VAL(I$):H$=HEX$(I)
4020 IF I$="" THEN 4000
4030 IF I<0 OR I>255 THEN 4000
4040 IF LEN(H$)<2 THEN H$="0"+H$
4050 PRINT "Sending P"+H$+"<CR>":REM SET DIGITAL OUTPUTS
4060 PRINT #1, "P"+H$
4070 RETURN
4080 REM ----------
4200 PRINT "Enter Analog Output 0 value in decimal from 0 to 4095: ";
4210 LINE INPUT I$:I=VAL(I$):H$=HEX$(I)
4220 IF I$="" THEN 4200
4230 IF I<0 OR I>4095 THEN 4200
4240 IF LEN(H$)<3 THEN H$="0"+H$:GOTO 4240
4250 PRINT "Sending A"+H$+"<CR>":REM SET ANALOG OUTPUT 0
4260 PRINT #1, "A"+H$
4270 RETURN
4280 REM ----------
4400 PRINT "Enter Analog Output 1 value in decimal from 0 to 4095: ";
4410 LINE INPUT I$:I=VAL(I$):H$=HEX$(I)
4420 IF I$="" THEN 4400
4430 IF I<0 OR I>4095 THEN 4400
4440 IF LEN(H$)<3 THEN H$="0"+H$:GOTO 4440
4450 PRINT "Sending B"+H$+"<CR>":REM SET ANALOG OUTPUT 1
4460 PRINT #1, "B"+H$
4470 RETURN
4480 REM ----------
4600 PRINT "Waveform Output will be continuous-"
4610 PRINT "Enter frequency value in decimal from 15 to 5000 HZ: ";
4620 LINE INPUT I$:I=VAL(I$)
4630 IF I$="" THEN 4600
4640 IF I=0 THEN 4660
4650 IF I<15 OR I>5000 THEN 4600
4660 H$=HEX$(I)
4670 IF LEN(H$)<4 THEN H$="0"+H$:GOTO 4670
4688 PRINT "Sending F"+H$+"<CR>":REM SET WAVEFORM FREQUENCY OUTPUT
4690 PRINT #1, "F"+H$
4700 RETURN
4710 REM ----------
4800 PRINT "Waveform Output used will be type 1 (92 HZ)-"
4810 PRINT "Enter duty cycle value in decimal from 1 to 99: ";
4820 LINE INPUT I$:I=VAL(I$)
4830 IF I$="" THEN 4800
4840 IF I=0 THEN 4860
4850 IF I<1 OR I>99 THEN 4800
4860 H$=HEX$(I)
4870 IF LEN(H$)<2 THEN H$="0"+H$
4880 PRINT "Sending W1"+H$+"<CR>":REM SET TYPE 1 WAVEFORM DUTY CYCLE OUTPUT
4890 PRINT #1, "W1"+H$
4900 RETURN
4990 REM ------- ERRORS DURING TERMINAL EMULATION -------
5000 IF ERR=57 THEN RESUME 5030:REM DEVICE I/O
5010 IF ERR=69 THEN RESUME 5060:REM COMMUNICATION BUFFER OVERFLOW
5020 END
5030 ON ERROR GOTO 0
5040 PRINT:PRINT "overrun, framing, parity, or break error":PRINT
5050 GOTO 2000
5060 ON ERROR GOTO 0
5070 PRINT:PRINT "receive buffer has overflowed - data will be missing":PRINT
5080 GOTO 2000
5090 REM ------- ERRORS OPENING COM PORT -------
5500 IF ERR=24 THEN RESUME 5530:REM DEVICE TIMEOUT
5510 IF ERR=68 THEN RESUME 5530:REM DEVICE UNAVAILABLE
5520 END
5530 ON ERROR GOTO 0
5540 CLS:PRINT PORT$+" is not available or is not responding"
5550 T=TIMER
5560 IF TIMER<T+3 THEN 5560
5570 GOTO 500
5580 REM ---------------------------------------------------------------------
6000 CLS
6010 LOCATE ,,0
6020 PRINT "Industrologic, Inc. SIO-1000 Demonstration/Test Program"
6030 PRINT "Continuous display/set functions"
6040 PRINT
6050 PRINT "The following is a list of commands that can be"
6060 PRINT "done continuously in a loop for test purposes:"
6070 PRINT
6080 PRINT "(D)  Display Digital Inputs"
6090 PRINT "(A)  Display Analog Input 0"
6100 PRINT "(B)  Display Analog Input 1"
6110 PRINT "(C)  Display Pulse Counter Input"
6120 PRINT "(O)  Set Digital Outputs on and off"
6130 PRINT "(V)  Set varying voltages at Analog Outputs"
6140 PRINT "(F)  Set varying frequencies at Waveform Output"
6150 PRINT "(W)  Set varying duty cycles at Waveform Output"
6160 PRINT "(K)  Turn Relay on and off"
6170 PRINT
6180 PRINT "Select function or hit ESCape to go back"
6190 ON ERROR GOTO 6400
6200 B$=INKEY$:IF B$="" THEN 6200
6210 IF B$="D" OR B$="d" THEN GOSUB 6500:GOTO 6000
6220 IF B$="A" OR B$="a" THEN GOSUB 7000:GOTO 6000
6230 IF B$="B" OR B$="b" THEN GOSUB 7500:GOTO 6000
6240 IF B$="C" OR B$="c" THEN GOSUB 8000:GOTO 6000
6250 IF B$="O" OR B$="o" THEN GOSUB 8500:GOTO 6000
6260 IF B$="V" OR B$="v" THEN GOSUB 8800:GOTO 6000
6270 IF B$="F" OR B$="f" THEN GOSUB 9200:GOTO 6000
6280 IF B$="W" OR B$="w" THEN GOSUB 9500:GOTO 6000
6290 IF B$="K" OR B$="k" THEN GOSUB 9800:GOTO 6000
6300 IF B$=CHR$(27) THEN ON ERROR GOTO 0:GOTO 1000
6310 GOTO 6200
6320 REM ------- ERRORS DURING CONTINUOUS DISPLAY/SET -------
6400 RESUME 6410
6410 ON ERROR GOTO 0
6420 GOTO 6000
6430 REM ----------
6500 CLS
6510 IF LOC(1)>0 THEN DUMMY$=INPUT$(LOC(1),#1):REM CLEAR RECEIVE BUFFER
6520 PRINT #1,"P":REM SEND COMMAND
6530 T=TIMER
6540 IF LOC(1)>=3 THEN 6630:REM CHECK FOR ENOUGH CHARACTERS RECEIVED
6550 IF TIMER>T+2 THEN 6580:REM NOT ENOUGH CHARACTERS IN TIME
6560 GOTO 6540
6570 REM ---
6580 CLS:PRINT "Timeout waiting for SIO-1000 to respond..."
6590 T=TIMER
6600 IF TIMER<T+2 THEN 6600
6610 RETURN
6620 REM ---
6630 P$=INPUT$(3,#1):REM GET RESPONSE
6640 P$=RIGHT$(P$,2):REM STRIP OFF THE VALUE
6650 LNG=LEN(P$):P=0:MULT=1:REM CONVERT HEX VALUE TO DECIMAL ALSO
6660 FOR DIGIT=LNG TO 1 STEP-1
6670 M$=MID$(P$,DIGIT,1)
6680 P=P+VAL("&H"+M$)*MULT
6690 MULT=MULT*16
6700 NEXT DIGIT
6710 REM ---
6720 LOCATE 1,1
6730 PRINT "Digital Input=";P$;" hex, ";
6740 IF (P AND 128)=128 THEN PRINT "1"; ELSE PRINT "0";:REM DISPLAY BINARY TOO
6750 IF (P AND 64)=64 THEN PRINT "1"; ELSE PRINT "0";
6760 IF (P AND 32)=32 THEN PRINT "1"; ELSE PRINT "0";
6770 IF (P AND 16)=16 THEN PRINT "1"; ELSE PRINT "0";
6780 IF (P AND 8)=8 THEN PRINT "1"; ELSE PRINT "0";
6790 IF (P AND 4)=4 THEN PRINT "1"; ELSE PRINT "0";
6800 IF (P AND 2)=2 THEN PRINT "1"; ELSE PRINT "0";
6810 IF (P AND 1)=1 THEN PRINT "1"; ELSE PRINT "0";
6820 PRINT " binary"
6830 PRINT "Hit ESCape to quit"
6840 IN$=INKEY$
6850 IF IN$=CHR$(27) THEN RETURN
6860 T=TIMER
6870 IF TIMER<T+.25 THEN 6870:REM DELAY
6880 GOTO 6510
6890 REM ----------
7000 CLS
7010 IF LOC(1)>0 THEN DUMMY$=INPUT$(LOC(1),#1):REM CLEAR RECEIVE BUFFER
7020 PRINT #1,"A":REM SEND COMMAND
7030 T=TIMER
7040 IF LOC(1)>=3 THEN 7130:REM CHECK FOR ENOUGH CHARACTERS RECEIVED
7050 IF TIMER>T+2 THEN 7080:REM NOT ENOUGH CHARACTERS IN TIME
7060 GOTO 7040
7070 REM ---
7080 CLS:PRINT "Timeout waiting for SIO-1000 to respond..."
7090 T=TIMER
7100 IF TIMER<T+2 THEN 7100
7110 RETURN
7120 REM ---
7130 A$=INPUT$(4,#1):REM GET RESPONSE
7140 AH$=RIGHT$(A$,3):REM STRIP OFF THE VALUE
7150 LNG=LEN(AH$):AD=0:MULT=1:REM CONVERT HEX VALUE TO DECIMAL ALSO
7160 FOR DIGIT=LNG TO 1 STEP-1
7170 M$=MID$(AH$,DIGIT,1)
7180 AD=AD+VAL("&H"+M$)*MULT
7190 MULT=MULT*16
7200 NEXT DIGIT
7210 AD$=STR$(AD):AD$=RIGHT$(AD$,LEN(AD$)-1):REM STRIP OFF LEADING SPACE
7220 IF LEN(AD$)<5 THEN AD$="0"+AD$:GOTO 7220:REM PAD WITH ZEROS
7230 REM ---
7240 LOCATE 1,1
7250 PRINT "Analog Input #0=";AH$;" hex, ";AD$;" decimal"
7260 PRINT "Hit ESCape to quit"
7270 IN$=INKEY$
7280 IF IN$=CHR$(27) THEN RETURN
7290 T=TIMER
7300 IF TIMER<T+.25 THEN 7300:REM DELAY
7310 GOTO 7010
7320 REM ----------
7500 CLS
7510 IF LOC(1)>0 THEN DUMMY$=INPUT$(LOC(1),#1):REM CLEAR RECEIVE BUFFER
7520 PRINT #1,"B":REM SEND COMMAND
7530 T=TIMER
7540 IF LOC(1)>=3 THEN 7630:REM CHECK FOR ENOUGH CHARACTERS RECEIVED
7550 IF TIMER>T+2 THEN 7580:REM NOT ENOUGH CHARACTERS IN TIME
7560 GOTO 7540
7570 REM ---
7580 CLS:PRINT "Timeout waiting for SIO-1000 to respond..."
7590 T=TIMER
7600 IF TIMER<T+2 THEN 7600
7610 RETURN
7620 REM ---
7630 B$=INPUT$(4,#1):REM GET RESPONSE
7640 BH$=RIGHT$(B$,3):REM STRIP OFF THE VALUE
7650 LNG=LEN(BH$):BD=0:MULT=1:REM CONVERT HEX VALUE TO DECIMAL ALSO
7660 FOR DIGIT=LNG TO 1 STEP-1
7670 M$=MID$(BH$,DIGIT,1)
7680 BD=BD+VAL("&H"+M$)*MULT
7690 MULT=MULT*16
7700 NEXT DIGIT
7710 BD$=STR$(BD):BD$=RIGHT$(BD$,LEN(BD$)-1):REM STRIP OFF LEADING SPACE
7720 IF LEN(BD$)<5 THEN BD$="0"+BD$:GOTO 7720:REM PAD WITH ZEROS
7730 REM ---
7740 LOCATE 1,1
7750 PRINT "Analog Input #1=";BH$;" hex, ";BD$;" decimal"
7760 PRINT "Hit ESCape to quit"
7770 IN$=INKEY$
7780 IF IN$=CHR$(27) THEN RETURN
7790 T=TIMER
7800 IF TIMER<T+.25 THEN 7800:REM DELAY
7810 GOTO 7510
7820 REM ----------
8000 CC$="C":CLS
8010 IF LOC(1)>0 THEN DUMMY$=INPUT$(LOC(1),#1):REM CLEAR RECEIVE BUFFER
8020 PRINT #1,CC$:REM SEND COMMAND
8030 T=TIMER
8040 IF LOC(1)>=4 THEN 8130:REM CHECK FOR ENOUGH CHARACTERS RECEIVED
8050 IF TIMER>T+2 THEN 8080:REM NOT ENOUGH CHARACTERS IN TIME
8060 GOTO 8040
8070 REM ---
8080 CLS:PRINT "Timeout waiting for SIO-1000 to respond..."
8090 T=TIMER
8100 IF TIMER<T+2 THEN 8100
8110 RETURN
8120 REM ---
8130 C$=INPUT$(5,#1):REM GET RESPONSE
8140 CH$=RIGHT$(C$,4):REM STRIP OFF THE VALUE
8150 LNG=LEN(CH$):CD=0:MULT=1:REM CONVERT HEX VALUE TO DECIMAL ALSO
8160 FOR DIGIT=LNG TO 1 STEP-1
8170 M$=MID$(CH$,DIGIT,1)
8180 CD=CD+VAL("&H"+M$)*MULT
8190 MULT=MULT*16
8200 NEXT DIGIT
8210 CD$=STR$(CD):CD$=RIGHT$(CD$,LEN(CD$)-1):REM STRIP OFF LEADING SPACE
8220 IF LEN(CD$)<5 THEN CD$="0"+CD$:GOTO 8220:REM PAD WITH ZEROS
8230 REM ---
8240 LOCATE 1,1
8250 PRINT "Pulse Counter Input=";CH$;" hex, ";CD$;" decimal"
8260 PRINT "Hit C to reset counter or ESCape to quit"
8270 IN$=INKEY$
8280 IF IN$=CHR$(27) THEN RETURN
8290 IF IN$="C" OR IN$="c" THEN CC$="c" ELSE CC$="C"
8300 T=TIMER
8310 IF TIMER<T+.25 THEN 8310:REM DELAY
8320 GOTO 8010
8330 REM ----------
8500 CLS
8510 PRINT "Setting Digital Outputs on and off sequentially...."
8520 PRINT "Hit ESCape to quit":ESCFLAG=0
8530 PRINT #1,"P80":GOSUB 8630:IF ESCFLAG THEN ESCFLAG=0:RETURN
8540 PRINT #1,"P40":GOSUB 8630:IF ESCFLAG THEN ESCFLAG=0:RETURN
8550 PRINT #1,"P20":GOSUB 8630:IF ESCFLAG THEN ESCFLAG=0:RETURN
8560 PRINT #1,"P10":GOSUB 8630:IF ESCFLAG THEN ESCFLAG=0:RETURN
8570 PRINT #1,"P08":GOSUB 8630:IF ESCFLAG THEN ESCFLAG=0:RETURN
8580 PRINT #1,"P04":GOSUB 8630:IF ESCFLAG THEN ESCFLAG=0:RETURN
8590 PRINT #1,"P02":GOSUB 8630:IF ESCFLAG THEN ESCFLAG=0:RETURN
8600 PRINT #1,"P01":GOSUB 8630:IF ESCFLAG THEN ESCFLAG=0:RETURN
8610 GOTO 8530
8620 REM ---
8630 PRINT ".";
8640 GOSUB 8680:IF ESCFLAG THEN RETURN
8650 PRINT #1,"P0"
8660 GOSUB 8680:IF ESCFLAG THEN RETURN
8670 RETURN
8680 IN$=INKEY$
8690 IF IN$=CHR$(27) THEN ESCFLAG=-1
8700 T=TIMER
8710 IF TIMER<T+.5 THEN 8710:REM DELAY
8720 RETURN
8730 REM ----------
8800 CLS
8810 PRINT "Sending voltage values from zero to maximum to Analog Outputs...."
8820 PRINT "Hit ESCape to quit"
8830 FOR I=0 TO 4095 STEP 5
8840 GOSUB 8950
8850 IF ESCFLAG THEN ESCFLAG=0:RETURN
8860 NEXT I
8870 PRINT ".";
8880 FOR I=4090 TO 10 STEP -5
8890 GOSUB 8950
8900 IF ESCFLAG THEN ESCFLAG=0:RETURN
8910 NEXT I
8920 PRINT ".";
8930 GOTO 8830
8940 REM -----
8950 H$=HEX$(I):REM CONVERT DECIMAL VALUE TO HEX STRING
8960 IF LEN(H$)<3 THEN H$="0"+H$:GOTO 8960:REM PAD STRING TO LENGTH OF 3
8970 PRINT #1, "A"+H$:REM SEND COMMANDS
8980 PRINT #1, "B"+H$
8990 IN$=INKEY$
9000 IF IN$=CHR$(27) THEN ESCFLAG=-1
9010 RETURN
9020 REM ----------
9200 CLS
9210 PRINT "Sending frequency values from 20 to 5000 HZ to Waveform Output...."
9220 PRINT "Hit ESCape to quit"
9230 FOR I=20 TO 5000 STEP 10
9240 GOSUB 9350
9250 IF ESCFLAG THEN ESCFLAG=0:RETURN
9260 NEXT I
9270 PRINT ".";
9280 FOR I=4990 TO 30 STEP -10
9290 GOSUB 9350
9300 IF ESCFLAG THEN ESCFLAG=0:RETURN
9310 NEXT I
9320 PRINT ".";
9330 GOTO 9230
9340 REM -----
9350 H$=HEX$(I):REM CONVERT DECIMAL VALUE TO HEX STRING
9360 IF LEN(H$)<4 THEN H$="0"+H$:GOTO 9360:REM PAD STRING TO LENGTH OF 4
9370 PRINT #1, "F"+H$:REM SEND COMMAND
9380 IN$=INKEY$
9390 IF IN$=CHR$(27) THEN ESCFLAG=-1
9400 RETURN
9410 REM ----------
9500 CLS
9510 PRINT "Sending duty cycle values from 5% to 95% to Waveform Output...."
9520 PRINT "Hit ESCape to quit"
9530 FOR I=5 TO 95
9540 GOSUB 9650
9550 IF ESCFLAG THEN ESCFLAG=0:RETURN
9560 NEXT I
9570 PRINT ".";
9580 FOR I=94 TO 6 STEP -1
9590 GOSUB 9650
9600 IF ESCFLAG THEN ESCFLAG=0:RETURN
9610 NEXT I
9620 PRINT ".";
9630 GOTO 9530
9640 REM -----
9650 H$=HEX$(I):REM CONVERT DECIMAL VALUE TO HEX STRING
9660 IF LEN(H$)<2 THEN H$="0"+H$:REM PAD STRING TO LENGTH OF 2
9670 PRINT #1, "W1"+H$:REM SEND DUTY CYCLE COMMAND FOR DUTY CYCLE TYPE 1
9680 IN$=INKEY$
9690 IF IN$=CHR$(27) THEN ESCFLAG=-1
9700 RETURN
9710 REM ----------
9800 CLS
9810 PRINT "Turning Relay on and off...."
9820 PRINT "Hit ESCape to quit"
9830 PRINT ".";
9840 PRINT #1,"K1"
9850 IN$=INKEY$
9860 IF IN$=CHR$(27) THEN RETURN
9870 T=TIMER
9880 IF TIMER<T+1 THEN 9880
9890 PRINT ".";
9900 PRINT #1,"K0"
9910 IN$=INKEY$
9920 IF IN$=CHR$(27) THEN RETURN
9930 T=TIMER
9940 IF TIMER<T+1 THEN 9940:REM DELAY
9950 GOTO 9830