NEW
--- clear storage area
1 GOSUB 220
--- read inputs to get mode
5 GOSUB 200
6 A=M
--- mode 6 requires 2 IR
7 B=6
8 IF A=B 100
--- wait for 1 valid IR
10 READIR
11 IF A=0 5
12 A=F
--- allow only buttons 1-8
13 B=7
14 IF A>B 5
--- visual feedback
20 LED=1
21 DELAY 1
22 LED=0
--- wait for button release
23 DELAY 4
--- clear any extra IR
24 READIR
25 IF A<>0 24
--- jump per mode
30 A=M
31 B=4
32 IF A<B 70
33 B=7
34 IF A=B 50
35 GOTO 5
--- toggle mode
50 A=F
51 A=240
52 B=F
53 A=A+B
54 C=A
55 READEE C
56 A=A+1
57 WRITEEE C
58 G=A
59 A=F
60 GOSUB 150
61 GOTO 5
--- pulsed mode
70 A=F
71 G=1
--- turn relay on
72 GOSUB 150
73 A=M
--- get delay from mode
74 B=0
75 IF A<>B 78
76 D=100
77 GOTO 90
78 B=1
79 IF A<>B 82
80 D=50
81 GOTO 90
82 B=2
83 IF A<>B 86
84 D=10
85 GOTO 90
86 D=5
--- delay
90 DELAY D
91 A=F
92 G=0
--- turn relay off
93 GOSUB 150
94 GOTO 5
--- two button mode 6
--- wait for first IR
100 READIR
101 IF A=0 5
102 A=F
--- allow only buttons 1-8
103 B=7
104 IF A>B 5
--- visual feedback on
105 LED=1
--- save button
106 C=A
--- wait for button release
107 DELAY 5
--- wait for second IR
110 READIR
111 IF A=0 110
112 A=F
--- check for vol up
113 B=18
114 IF A=B 120
--- check for vol down
115 B=19
116 IF A=B 122
117 GOTO 110
120 G=1
121 GOTO 125
122 G=0
--- visual feedback off
125 LED=0
--- wait for button release
126 DELAY 5
130 A=C
--- set relay on/off
131 GOSUB 150
132 GOTO 5
--- 0-7 in A selects relay
--- on/off value in G
150 A=A*2
151 A=A+160
152 GOTO A
160 RELAY1=G
161 RETURN
162 RELAY2=G
163 RETURN
164 RELAY3=G
165 RETURN
166 RELAY4=G
167 RETURN
168 RELAY5=G
169 RETURN
170 RELAY6=G
171 RETURN
172 RELAY7=G
173 RETURN
174 RELAY8=G
175 RETURN
--- read inputs to get mode
200 A=0
201 IF DI1=0 203
202 A=A+4
203 IF DI2=0 205
204 A=A+2
205 IF DI3=0 207
206 A=A+1
207 M=A
208 RETURN
--- clear storage area
220 C=240
221 LOOP 8
222 A=0
223 B=0
224 WRITEEE C
225 A=C
226 A=A+1
227 C=A
228 ENDLOOP
229 RETURN
-------------------------------
irpkg.tmb for the RC51-IR

Checks mode of operation by
reading logic level at digital
inputs DI1, DI2, DI3. H=logic
high (not grounded), L=logic
low (grounded).

DI1 DI2 DI3 MODE
 H   H   H   7   DEFAULT
 H   H   L   6

 H   L   H   N/A
 H   L   L   N/A
                 DELAY TIME
 L   H   H   3   0.5 SEC
 L   H   L   2   1 SEC
 L   L   H   1   5 SEC
 L   L   L   0   10 SEC

Mode 7. Alternates relays 1-8
on/off when buttons 1-8 are
pressed.

Mode 6. Operates relays 1-8
when buttons 1-8 are pressed
followed by Volume Up (relay
on) or Volume Down (relay
off) button.

Modes 3, 2, 1, and 0. Momen-
tarily turns on relays 1-8
when buttons 1-8 are pressed.
The amount of time the relays
are on is specified by the
mode selected.