disprtc.tmb for the IC51
Display and optionally set
the real-time clock.
Exit if escape key pressed.
-------------------------------
NEW
--- SHOW HOW TO SET CLOCK
1 PRINT "S"
2 PRINT "="
3 PRINT "S"
4 PRINT "e"
5 PRINT "t"
6 PRINT 13
7 PRINT 10
--- SEE IF THERE IS ANY CHARACTER AT SERIAL PORT
10 A=KEY
--- END PROGRAM IF ESCAPE KEY
11 B=27
12 IF A<>B 14
13 END
--- CHECK FOR "s" 
14 B=115
15 IF A<>B 18
--- SET CLOCK IF MATCH
16 GOSUB 300
17 GOTO 25
--- CHECK FOR "S" 
18 B="S"
19 IF A<>B 25
--- SET CLOCK IF MATCH
20 GOSUB 300
--- READ REAL-TIME CLOCK
25 READRTC
--- GET SECONDS
26 A=S
--- GET OLD SECONDS
27 B=C
--- LOOP BACK IF SECONDS ARE SAME AS OLD SECONDS
28 IF A=B 10
--- SAVE CURRENT SECONDS AS OLD
29 C=S
--- DISPLAY TIME AND DATE
--- GET HOUR
30 A=H
31 GOSUB 100
32 PRINT ":"
--- GET MINUTE
40 A=M
41 GOSUB 100
42 PRINT ":"
--- GET SECOND
50 A=S
51 GOSUB 100
52 PRINT " "
--- GET MONTH
60 A=N
61 GOSUB 100
62 PRINT "/"
--- GET DAY
70 A=D
71 GOSUB 100
72 PRINT "/"
--- GET YEAR
80 A=Y
81 GOSUB 100
82 PRINT " "
--- GET DAY OF WEEK
90 A=W
91 GOSUB 200
--- CARRIAGE RETURN/LINE FEED
93 PRINT 13
94 PRINT 10
95 GOTO 10
--- PRINT VALUE IN A AS TWO DIGITS
100 B=9
101 IF A>B 103
102 PRINT "0"
103 PRINT A
104 RETURN
--- PRINT DAY OF WEEK BASED ON NUMBER
200 IF A=0 206
201 B=7
202 IF A>B 206
--- CALCULATE LINE NUMBER OFFSET
203 A=A*5
204 A=A+205
205 GOTO A
206 RETURN
--- LINE NUMBER OFFSET HAS BEEN CALCULATED
210 PRINT "S"
211 PRINT "u"
212 PRINT "n"
213 RETURN
215 PRINT "M"
216 PRINT "o"
217 PRINT "n"
218 RETURN
220 PRINT "T"
221 PRINT "u"
222 PRINT "e"
223 RETURN
225 PRINT "W"
226 PRINT "e"
227 PRINT "d"
228 RETURN
230 PRINT "T"
231 PRINT "h"
232 PRINT "u"
233 RETURN
235 PRINT "F"
236 PRINT "r"
237 PRINT "i"
238 RETURN
240 PRINT "S"
241 PRINT "a"
242 PRINT "t"
243 RETURN
--- SET CLOCK ROUTINE
--- GET HOURS
300 PRINT "H"
301 PRINT "o"
302 PRINT "u"
303 PRINT "r"
304 PRINT ":"
305 INPUT H
--- GET MINUTES
310 PRINT "M"
311 PRINT "i"
312 PRINT "n"
313 PRINT ":"
314 INPUT M
--- GET SECONDS
320 PRINT "S"
321 PRINT "e"
322 PRINT "c"
323 PRINT ":"
324 INPUT S
--- GET MONTH
330 PRINT "M"
331 PRINT "o"
332 PRINT "n"
333 PRINT ":"
334 INPUT N
--- GET DAY
340 PRINT "D"
341 PRINT "a"
342 PRINT "y"
343 PRINT ":"
344 INPUT D
--- GET YEAR
350 PRINT "Y"
351 PRINT "e"
352 PRINT "a"
353 PRINT "r"
354 PRINT ":"
355 INPUT Y
--- GET DAY OF WEEK
360 PRINT "D"
361 PRINT "O"
362 PRINT "W"
363 PRINT ":"
364 INPUT W
---
370 WRITERTC
371 RETURN